Die Feststelltaste nimmt erstklassigen Platz auf der Tastatur ein und zieht ihr Gewicht nicht auf. Dieses einfache AutoHotkey-Skript verwandelt die Feststelltaste in eine Modifikatortaste, sodass Sie sie für anpassbare Verknüpfungen verwenden können.
Inhaltsverzeichnis
Die Grundlagen
Mit diesem Skript können Sie Feststelltaste + G drücken, um schnell Text von überall in Windows zu Google oder Feststelltaste + D drücken, um die Wörterbuchdefinition eines Wortes nachzuschlagen. Diese Verknüpfungen sind natürlich anpassbar.
Und das Beste ist, dass Sie mit diesem cleveren Skript die Feststelltaste immer noch normal verwenden können. Sie können die Feststelltaste ein- und ausschalten, indem Sie sie zweimal schnell drücken. Wenn Sie dies nicht tun, fungiert die Feststelltaste als Zusatztaste für Verknüpfungen.
AutoHotkey 101
AutoHotkey ist eine kostenlose Windows-Anwendung, die im Hintergrund sitzt und Skripte ausführt. Sie können diese Skripte selbst schreiben oder herunterladen. Skripte warten im Allgemeinen auf einen Tastendruck und führen eine Aktion aus. Auf diese Weise ist AutoHotkey eine schnelle Möglichkeit, Tasten in Windows neu zuzuordnen oder Tasten unterschiedliche Aktionen zuzuweisen.
Wir haben beispielsweise gezeigt, wie Sie AutoHotkey verwenden können, um die Windows-Taste zu deaktivieren, um zu verhindern, dass das Startmenü geöffnet wird und Sie PC-Spiele im Vollbildmodus verlassen. Sie müssen die Tastenkappe nicht von der Tastatur lösen.
Installieren Sie AutoHotkey und holen Sie sich das Skript
AutoHotkey herunterladen und installieren Sie es, um zu beginnen. Laden Sie als Nächstes das CapsLock Modifier-Skript herunter.
Extrahieren Sie die AHK-Skriptdatei aus der ZIP-Archivdatei und legen Sie sie in einem beliebigen Ordner auf Ihrem Computer ab. Um es mit AutoHotkey auszuführen, klicken Sie mit der rechten Maustaste auf das Skript und wählen Sie „Skript ausführen“.
Das Skript läuft nun im Hintergrund. Um die Feststelltaste ein- und auszuschalten, tippen Sie schnell zweimal auf die Feststelltaste.
Wenn Sie nicht doppeltippen, fungiert die Feststelltaste nur als Modifikatortaste. Mit den in das Skript integrierten Funktionen können Sie die folgenden Verknüpfungen überall in Windows verwenden:
Drücken Sie Feststelltaste + d, um die Wörterbuchdefinition eines ausgewählten Wortes zu finden.
Drücken Sie Feststelltaste + g, um Google an einer beliebigen Stelle in Windows nach dem ausgewählten Text zu durchsuchen.
Drücken Sie Feststelltaste + t, um das ausgewählte Wort in einem Thesaurus zu suchen.
Drücken Sie Feststelltaste + w, um auf Wikipedia nach dem ausgewählten Text zu suchen.
Möchten Sie mehr Verknüpfungen? Sie können mit ein wenig Wissen über AutoHotkey-Skripte Ihre eigenen erstellen.
Um AutoHotkey zu steuern, suchen Sie in Ihrem Infobereich nach dem AutoHotkey-Symbol – es hat einen grünen Hintergrund mit einem weißen H darauf. Um die Ausführung des Skripts zu beenden, klicken Sie einfach mit der rechten Maustaste auf das AutoHotkey-Symbol und wählen Sie „Beenden“.
Wie funktioniert es?
Wenn Sie sehen möchten, was das Skript macht, klicken Sie mit der rechten Maustaste darauf und wählen Sie stattdessen „Skript bearbeiten“. Dadurch wird das Skript in Notepad geöffnet und Sie können seinen Code untersuchen. Das Skript ist ziemlich kurz und leicht verständlich. Wir empfehlen, keine seltsamen Skripte herunterzuladen und auszuführen, ohne sie sich zuerst anzusehen und zu verstehen.
Dieses Skript wurde uns von Dave Kellog zugesandt. Hier ist der magische Teil des Skripts, der Caps Lock als Modifikatortaste funktionieren lässt, wenn es zweimal gedrückt wird:
CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return
Dieses Bit wartet, um zu sehen, ob die Feststelltaste zweimal gedrückt wird, und schaltet die Feststelltaste ein oder aus. Andernfalls erfasst das Skript die Feststelltaste und verwendet sie für Modifikator-Shortcuts.
Der Rest des Skripts enthält die Shortcut-Aktionen und eine hilfreiche Zwischenablagefunktion, die den Inhalt Ihrer Zwischenablage speichert und wiederherstellt. Dieser Teil ist ziemlich notwendig, da die Modifikatorfunktionen die Zwischenablage verwenden, um Aktionen für den ausgewählten Text auszuführen.
Möchten Sie das vollständige Skript sehen, ohne es herunterzuladen? Hier ist es:
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn ; Enable warnings to assist with detecting common errors.
#SingleInstance FORCE ; Skip invocation dialog box and silently replace previously executing instance of this script.
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
;================================================================================================
; CapsLock processing. Must double tap CapsLock to toggle CapsLock mode on or off.
;================================================================================================
; Must double tap CapsLock to toggle CapsLock mode on or off.
CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return
;================================================================================================
; Hot keys with CapsLock modifier. See https://autohotkey.com/docs/Hotkeys.htm#combo
;================================================================================================
; Get DEFINITION of selected word.
CapsLock & d::
ClipboardGet()
Run, http://www.google.com/search?q=define+%clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
; GOOGLE the selected text.
CapsLock & g::
ClipboardGet()
Run, http://www.google.com/search?q=%clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
; Do THESAURUS of selected word
CapsLock & t::
ClipboardGet()
Run http://www.thesaurus.com/browse/%Clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
; Do WIKIPEDIA of selected word
CapsLock & w::
ClipboardGet()
Run, https://en.wikipedia.org/wiki/%clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;================================================================================================
; Clipboard helper functions.
;================================================================================================
ClipboardGet()
{
OldClipboard:= ClipboardAll ;Save existing clipboard.
Clipboard:= ""
Send, ^c ;Copy selected test to clipboard
ClipWait 0
If ErrorLevel
{
MsgBox, No Text Selected!
Return
}
}
ClipboardRestore()
{
Clipboard:= OldClipboard
}
Wir haben zuvor AutoHotkey-Skripte gesehen, die Caps Lock in eine Modifikatortaste verwandeln, aber noch nie eines, das Caps Lock als Umschalter beibehält, wenn Sie es zweimal drücken. Es ist sehr clever. Nochmals vielen Dank an Dave Kellog für die Zusendung.